home *** CD-ROM | disk | FTP | other *** search
/ ShareWare OnLine 2 / ShareWare OnLine Volume 2 (CMS Software)(1993).iso / bbs_soft / mrun210.zip / MRUN210B.WAS < prev    next >
Text File  |  1993-04-28  |  10KB  |  390 lines
  1. ;MailRun v2.10:  Part B, changesettings
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to changing MailRun
  9. * settings.  It puts up the MailRun Settings dialog box, and
  10. * writes any changes to the *.MRN file.  If the user changes
  11. * the MailRun directory, it will move all MailRun Files to the
  12. * new directory and stop the script.
  13. * 
  14. **************************************************************************
  15. **************************************************************************
  16. #endcomment
  17.  
  18. #define MRUN210B
  19. #define MRUN210BC
  20. #define MRUN210AB
  21.  
  22. #include "mrun210.h"
  23.  
  24. #comment
  25. *********************************************************************
  26. * 
  27. * MAIN()
  28. * 
  29. * Calls checkchild(), checkdir(), settingsbox(),
  30. * loadsettings(), changemailrun(), makemailrunlist(),
  31. * menudim(), newmailrun(), interfaceon(), changemrundir(),
  32. * writesettings(), findstring(), checkchanged(),
  33. * 
  34. * Allows the user to change the settings in the [MailRun]
  35. * section of the *.MRN file.
  36. * 
  37. *********************************************************************
  38. #endcomment
  39.  
  40. proc main
  41. string LastMRunDir, LastMailDir, LastReplyDir
  42. string LastDLDir, LastULDir, LastMRun
  43. integer dialogstatus
  44.     menudim()
  45.     checkchild()
  46.     LastMRun = MailRun
  47.     loadsettings()
  48.     LastMailDir = MailDir
  49.     LastReplyDir = ReplyDir
  50.     LastDLDir = DownloadDir
  51.     LastULDir = UploadDir
  52.     if FLAGS & DEFAULTS
  53.         MailRunList = "mailrun.ini"
  54.         MailRunTrunc = "mailrun.ini"
  55.         LastMRunDir = MailRunDir
  56.     else
  57.         findfirst MailRun
  58.         MailRunTrunc = $FILENAME
  59.         makemailrunlist()
  60.     endif
  61.     FLAGS &= UNCHANGED
  62.     settingsbox()
  63.     if !(FLAGS & DEFAULTS)
  64.         disable CTRL 242
  65.     endif
  66.     if LogRun == 0
  67.         disable CTRL 71
  68.         disable CTRL 72
  69.     endif
  70.     if FLAGS & RUNNING
  71.         disable CTRL 170
  72.     endif
  73.     if FLAGS & NEW
  74.         newmailrun()
  75.         getfirstitem()
  76.         LastMRun = MailRun
  77.     endif
  78.     interfaceon()
  79.     while 1
  80.         dialogstatus = $DIALOG
  81.         switch dialogstatus
  82.             case 10
  83.                 ;User selected "Save"
  84.                 ;if the directories chosen in settingsbox()
  85.                 ;don't exist, create them
  86.                 if checkdir(&MailRunDir, LastMRunDir) && \
  87.                     checkdir(&MailDir, LastMailDir) && \
  88.                     checkdir(&ReplyDir, LastReplyDir) && \
  89.                     checkdir(&DownloadDir, LastDLDir) && \
  90.                     checkdir(&UploadDir, LastULDir)
  91.                     ;if all directories were successfully created...
  92.                     chdir MailRunDir
  93.                     writesettings()
  94.                 else
  95.                     updatedlg 128
  96.                 endif
  97.                 FLAGS &= UNCHANGED
  98.             endcase
  99.             case 11
  100.                 ;User selected "Done"
  101.                 if checkchanged()
  102.                     ;if user has no unsaved changes...
  103.                     if (FLAGS & DEFAULTS) && !(findstring(LastMRunDir, MailRunDir))
  104.                         ;if user has changed the MailRun Directory    
  105.                         changemrundir(LastMRunDir)
  106.                         updatedlg 128
  107.                     else
  108.                         exit
  109.                     endif
  110.                 endif
  111.             endcase
  112.             case 70
  113.                 ;User selected the Log MailRun checkbox
  114.                 if LogRun == 0
  115.                     ;If logging was turned off, disable the other checkboxes
  116.                     disable CTRL 71
  117.                     disable CTRL 72
  118.                 else
  119.                     ;Otherwise, enable the checkboxes
  120.                     enable CTRL 71
  121.                     enable CTRL 72
  122.                 endif
  123.                 FLAGS |= CHANGED
  124.                 updatedlg 1
  125.             endcase
  126.             case 170
  127.                 ;User changed mailrun with combobox
  128.                 if checkchanged()
  129.                     changemailrun()
  130.                     getfirstitem()
  131.                     LastMRun = MailRun
  132.                     updatedlg -1
  133.                 else
  134.                     findfirst MailRun
  135.                     MailRunTrunc = $FILENAME
  136.                     updatedlg 512
  137.                 endif
  138.             endcase
  139.             case 230
  140.             case 231
  141.             case 232
  142.             case 233
  143.             case 234
  144.             case 235
  145.             case 236
  146.             case 237
  147.             case 238
  148.             case 239
  149.             case 240
  150.             case 241
  151.             case 242
  152.             case 71
  153.             case 72
  154.             case 73
  155.                 FLAGS |= CHANGED
  156.             endcase
  157.         endswitch
  158.     endwhile
  159. endproc
  160.  
  161.  
  162. #comment
  163. *********************************************************************
  164. * 
  165. * CHECKDIR()
  166. * 
  167. * Called by main()
  168. * 
  169. * Creates a directory.  If the directory already exists or
  170. * was successfully created, a value of 0 is returned.  If
  171. * an error occurs, the name of NewDir is changed to that
  172. * of OldDir, and a value of 1 is returned.
  173. * 
  174. *********************************************************************
  175. #endcomment
  176.  
  177. func checkdir : integer
  178. strparm NewDir, OldDir
  179.     chdir NewDir
  180.     if FAILURE
  181.         mkdir NewDir
  182.         if FAILURE
  183.             usermsg "Unable to create directory %s" NewDir
  184.             NewDir = OldDir
  185.             return 0
  186.         endif
  187.     endif
  188.     return 1
  189. endfunc
  190.  
  191.  
  192. #comment
  193. *********************************************************************
  194. * 
  195. * NEWMAILRUN()
  196. * 
  197. * Called by main()
  198. * 
  199. * Calls fverify(), filesave(), makemrn(), makemailrunlist(),
  200. * makefullname()
  201. * 
  202. * Prompts the user for the name of a new *.MRN file, checks
  203. * the name, and calls routines to create it.
  204. * 
  205. *********************************************************************
  206. #endcomment
  207.  
  208. proc newmailrun
  209. string NewRun, temp
  210.     ;Make sure the entered MailRun ID is the correct length
  211.     ;and that it doesn't already exist
  212.     while 1
  213.         NewRun = ""
  214.         sdlginput "New MailRun" \
  215.             "Enter the ID of the new mailrun:" NewRun
  216.         if FAILURE
  217.             exit
  218.         endif
  219.         strlwr NewRun
  220.         if not fverify(NewRun)
  221.             usermsg \
  222.             "A mailrun ID must be a valid DOS file name without the extension."
  223.             loopwhile
  224.         endif
  225.         strfmt temp "%s.mrn" NewRun
  226.         NewRun = makefullname(MailRunDir, temp)
  227.         if isfile NewRun
  228.             errormsg "That MailRun already exists!"
  229.         else
  230.             exitwhile
  231.         endif
  232.     endwhile
  233.  
  234.     ;Update the previous mailrun
  235.     filesave()
  236.     delfile MailRun
  237.     ;Create the new mailrun
  238.     MailRunTrunc = temp
  239.     makemrn()
  240.     makemailrunlist()
  241.     updatedlg -1
  242. endproc
  243.  
  244.  
  245. #comment
  246. *********************************************************************
  247. * 
  248. * CHANGEMRUNDIR()
  249. * 
  250. * Called by main()
  251. * 
  252. * Calls movefiles(), fileexit(), makefullname()
  253. * 
  254. * Requests confirmation, moves all MailRun support files
  255. * to the new MailRun Directory, and shuts down so that the
  256. * user can restart.
  257. * 
  258. *********************************************************************
  259. #endcomment
  260.  
  261. proc changemrundir
  262. strparm LastMRunDir
  263. string WarnMsg, CleanupFile
  264. integer Response
  265.     strfmt WarnMsg "All MailRun files will be moved to`r`n`r`n\
  266.       %s`r`n`r`nand MailRun will have to be restarted.`r`n`r`nDo you wish \
  267. continue?" MailRunDir
  268.     sdlgmsgbox "MailRun Message" WarnMsg QUESTION YESNO Response 2
  269.     switch Response
  270.         case 6
  271.             ;User selected "Yes"
  272.             cleanupfile = makefullname(TempDir, "CLEANUP.TMP")
  273.             profilerd cleanupfile "cleanup" "LastMRun" MailRun
  274.             findfirst MailRun
  275.             MailRunTrunc = $FILENAME
  276.             profilewr MailRunIni "MailRun" "MailRunDir" MailRunDir
  277.             movefiles(LastMRunDir, MailRunDir, "MRUN210?.WA?")
  278.             movefiles(LastMRunDir, MailRunDir, "MRUN210.H")
  279.             movefiles(LastMRunDir, MailRunDir, "NEWFILES.WA?")
  280.             movefiles(LastMRunDir, MailRunDir, "TERMINAL.WA?")
  281.             movefiles(LastMRunDir, MailRunDir, "*.MRN")
  282.             movefiles(LastMRunDir, MailRunDir, "*.?DX")
  283.             movefiles(LastMRunDir, MailRunDir, "*.?BF")
  284.             movefiles(LastMRunDir, MailRunDir, "MRUNICON.DLL")
  285.             movefiles(LastMRunDir, MailRunDir, "MAILRUN.WRI")
  286.             fileexit()
  287.         endcase
  288.         case 7
  289.             ;User selected "No"
  290.             MailRunDir = LastMRunDir
  291.         endcase
  292.     endswitch
  293. endproc    
  294.  
  295.  
  296. #comment
  297. *********************************************************************
  298. * 
  299. * MOVEFILES()
  300. * 
  301. * Called by changemrundir()
  302. * 
  303. * Calls makefullname()
  304. * 
  305. * Moves files matching the given filespec from their current
  306. * location to the MailRun directory.
  307. * 
  308. *********************************************************************
  309. #endcomment
  310.  
  311. proc movefiles
  312. strparm OldDir, NewDir, Spec
  313. string OldFile, NewFile, OldSpec
  314.     OldSpec = makefullname(OldDir, Spec)
  315.     findfirst OldSpec
  316.     while FOUND
  317.         if not strcmpi $FILENAME "MRUN210.WAS"
  318.             if not strcmpi $FILENAME "MRUN210.WAX"
  319.                statmsg "Moving %s" $FILENAME
  320.                 OldFile = makefullname(OldDir, $FILENAME)
  321.                 NewFile = makefullname(NewDir, $FILENAME)
  322.                 copyfile OldFile NewFile
  323.                 delfile OldFile
  324.             endif
  325.         endif
  326.         findnext
  327.     endwhile
  328. endproc
  329.  
  330.  
  331. #comment
  332. *********************************************************************
  333. * 
  334. * SETTINGSBOX()
  335. * 
  336. * Called by main()
  337. * 
  338. * Displays the MailRun Settings dialog box.
  339. * 
  340. *********************************************************************
  341. #endcomment
  342.  
  343. proc settingsbox
  344. destroydlg
  345. HelpPage = 4
  346. dialogbox 15 36 340 222 15 "MailRun Settings" HELPID HelpPage
  347.    groupbox 10 28 200 96 "Directories" shadow
  348.    text  16 42 71 8 right "MailRun Directory:"
  349.    text  16 58 71 8 right "Mail Directory:"
  350.    text  16 74 71 8 right "Reply Directory:"
  351.    text  16 90 71 8 right "Download Directory:"
  352.    text  16 106 71 8 right "Upload Directory:"
  353.    editbox 91 56 110 12 MailDir
  354.    editbox 91 72 110 12 ReplyDir
  355.    editbox 91 88 110 12 DownloadDir
  356.    editbox 91 104 110 12 UploadDir
  357.    groupbox 224 28 102 96 "Parameters" shadow
  358.    text  234 42 62 8 right "Dial Attempts:"
  359.    text  234 58 62 8 right "Dial Timeout:"
  360.    text  234 74 62 8 right "Dial Pause:"
  361.    text  234 90 62 8 right "Idle Timeout:"
  362.    text  234 106 62 8 right "Packets to Save:"
  363.    editbox 300 40 16 12 DialAttempts
  364.    editbox 300 56 16 12 DialTimeout
  365.    editbox 300 72 16 12 DialPause
  366.    editbox 300 88 16 12 IdleTime
  367.    editbox 300 104 16 12 SavePackets
  368.    groupbox 10 132 124 59 "Logging" shadow
  369.    checkbox 18 144 112 12 "Capture mailrun to log file" LogRun
  370.    checkbox 18 158 112 12 "Append to existing log file" AppendLog
  371.    checkbox 18 172 112 12 "Capture ANSI codes in log file" AnsiInLog
  372.    checkbox 18 200 134 12 "Filter duplicates from d/l database" NewfileFilter
  373.    groupbox 144 132 184 59 "Utilities" shadow
  374.    text  145 146 65 8 right "Archive Utility:"
  375.    text  145 160 65 8 right "QWK Mail Reader:"
  376.    text  145 174 65 8 right "Log File Viewer:"
  377.    editbox 214 144 107 12 Archiver
  378.    editbox 214 158 107 12 QWKReader
  379.    editbox 214 172 107 12 LogViewer
  380.    pushbutton 191 200 40 14 "&Save" normal default
  381.    pushbutton 252 200 40 14 "&Done" normal
  382.    text  100 11 52 8 right "Settings for:"
  383.    combobox 156 9 72 42 MailRunList MailRunTrunc sort
  384.    editbox 91 40 110 12 MailRunDir
  385. enddialog
  386. endproc
  387.  
  388.  
  389.  
  390.